;invitpHNcpl
;a modified version of invitp:
;no 1H decoupling during 15N evolution
;no 15N decoupling during the acquisition
;avance-version
;2D H-1/X correlation via double inept transfer
;phase sensitive using TPPI
;with decoupling during acquisition
;G. Bodenhausen & D.J. Ruben, Chem. Phys. Lett. 69, 185 (1980)


;#include <Avance.incl>


"p2=p1*2"
"p4=p3*2"
"d0=3u"
"d4=1s/(cnst2*4)"
"d11=30m"


1 ze
d11 pl12:f2
2 d1 do:f2
3 (p1 ph1)
d4 pl2:f2
(p2 ph2) (p4 ph5):f2
d4
(p1 ph3) (p3 ph6):f2
d0
; (p2 ph2)
d0
(p1 ph4) (p3 ph7):f2
d4
(p2 ph2) (p4 ph5):f2
d4 pl12:f2
go=2 ph31 ;cpd2:f2
d1 do:f2 wr #0 if #0 id0 ip6 zd
lo to 3 times td1
exit



ph1=0
ph2=0
ph3=1
ph4=1
ph5=0 0 0 0 2 2 2 2
ph6=0 2
ph7=0 0 2 2
ph31=0 2 2 0


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel - 90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;d0 : incremented delay (2D) [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d11: delay for disk I/O [30 msec]
;in0: 1/(4 * SW(X)) = (1/2) DW(X)
;nd0: 4
;NS: 4 * n
;DS: 16
;td1: number of experiments
;MC2: TPPI
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence

---

Go Back